neiam /dms

plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.android)
    alias(libs.plugins.kotlin.compose)
    alias(libs.plugins.kotlin.serialization)
}

// Bumped by hand for a real release; the build metadata after it comes
// from CI.
val baseVersion = "0.1.0"

android {
    namespace = "org.neiam.dms.app"
    compileSdk = 34

    defaultConfig {
        applicationId = "org.neiam.dms.app"
        minSdk = 26
        targetSdk = 34
        // Android refuses an update whose versionCode isn't higher than
        // what's installed, and F-Droid orders versions by it — so a
        // hardcoded 1 means no phone ever sees a second release. It also
        // means every CI build publishes the same filename with
        // different bytes, which the registry correctly refuses with a
        // 409.
        //
        // The CI run number is monotonic and needs no state kept
        // anywhere. Local builds stay at 1, which is fine: they are
        // never published.
        versionCode = (System.getenv("GITHUB_RUN_NUMBER") ?: "").toIntOrNull() ?: 1

        // The commit is what you want when someone reports a bug
        // against a build. Local builds just say "dev".
        versionName = "$baseVersion+" + ((System.getenv("GITHUB_SHA") ?: "dev").take(7))
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }
    kotlinOptions {
        jvmTarget = "17"
    }
    buildFeatures {
        compose = true
    }

    lint {
        // `assembleRelease` is a packaging step here, not a review gate.
        //
        // lintVital doubles the release build and fails for reasons that
        // have nothing to do with the code: lint throws on JDK 25 with
        // only the version string ("25.0.4.1") as the error, so a release
        // built on a modern local JDK fails while the same commit builds
        // fine in the container's JDK.
        //
        // Lint still runs on demand: ./gradlew :app:lint
        checkReleaseBuilds = false
    }
    packaging {
        resources {
            excludes += "/META-INF/{AL2.0,LGPL2.1}"
        }
    }
}

dependencies {
    implementation(libs.androidx.core.ktx)
    implementation(libs.androidx.lifecycle.runtime)
    implementation(libs.androidx.lifecycle.viewmodel.compose)
    implementation(libs.androidx.activity.compose)
    implementation(libs.androidx.navigation.compose)
    implementation(libs.androidx.security.crypto)

    implementation(platform(libs.compose.bom))
    implementation(libs.compose.ui)
    implementation(libs.compose.ui.tooling.preview)
    implementation(libs.compose.material3)
    implementation(libs.compose.material.icons)
    debugImplementation(libs.compose.ui.tooling)

    implementation(libs.coil.compose)
    implementation(libs.kotlinx.coroutines)

    implementation(libs.kotlinx.serialization.json)
    implementation(libs.retrofit)
    implementation(libs.retrofit.kotlinx.serialization)
    implementation(libs.okhttp)
    implementation(libs.okhttp.logging)

    implementation(libs.zxing.android.embedded)
}